1.2. Wat is het aantal cliënten per leveringsvorm VPT, MPT, DTV en PGB?

Concepten

• Leveringsvorm
• Mens
• Wlz-indicatie
• ZorgEnVerpleegProces

Relaties

• gaat over
• gedefinieerd door
• heeft deel

Eigenschappen

• einddatum
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 1.2
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
7PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
9
10SELECT
11   ("Totaal organisatie" AS ?Indeling)
12  (SUM(?hasVPT) AS ?Aantal_VPT)
13  (SUM(?hasMPT) AS ?Aantal_MPT)
14  (SUM(?hasDTV) AS ?Aantal_DTV)
15  (SUM(?hasPGB) AS ?Aantal_PGB)
16WHERE {
17  {
18    SELECT
19      ?client
20      (MAX(?vpt) AS ?hasVPT)
21      (MAX(?mpt) AS ?hasMPT)
22      (MAX(?pgb) AS ?hasPGB)
23      (MAX(?verblijf) AS ?hasVerblijf)
24    WHERE {
25            
26      #BIND(2024 AS ?jaar)
27      #BIND("Q1" AS ?kwartaal)
28
29      BIND(
30        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
31        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
32        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
33        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
34           '' )))) AS ?start_periode)
35
36      BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
37
38      ?zorgproces a onz-g:CureAndCareProcess ;
39                  onz-g:definedBy ?indicatie ;
40                  onz-g:startDatum ?start_zorgproces .
41      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
42      FILTER(?start_zorgproces <= ?eind_periode && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?start_periode ))
43
44      ?indicatie a onz-zorg:WlzIndicatie ;
45                 onz-g:hasPart ?lv ;
46                 onz-g:isAbout ?client ;
47                 onz-g:startDatum ?start_indicatie .
48      ?client a onz-g:Human .
49      ?lv a onz-zorg:Leveringsvorm ; rdfs:label ?leveringsvorm_label .
50
51      # Indicatie periode filter 
52      OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie }
53      FILTER(?start_indicatie <= ?eind_periode && ((?eind_indicatie >= ?start_periode) || (!BOUND(?eind_indicatie))))
54
55      BIND(IF(?lv = onz-zorg:instelling, 1, 0) AS ?verblijf)
56      BIND(IF(?lv = onz-zorg:vpt,        1, 0) AS ?vpt)
57      BIND(IF(?lv = onz-zorg:mpt,        1, 0) AS ?mpt)
58      BIND(IF(?lv = onz-zorg:pgb,        1, 0) AS ?pgb)
59    }
60    GROUP BY ?client
61  }
62  BIND(
63    IF((?hasVerblijf = 1) && ((?hasMPT = 1) || (?hasPGB = 1)), 1, 0)
64    AS ?hasDTV
65  )
66}
67